UI: Tweak Sequencer Sidebar panels
[blender.git] / make.bat
1 @echo off
2 REM This batch file does an out-of-source CMake build in ../build_windows
3 REM This is for users who like to configure & build Blender with a single command.
4 setlocal EnableDelayedExpansion
5 setlocal ENABLEEXTENSIONS
6 set BLENDER_DIR=%~dp0
7
8 call "%BLENDER_DIR%\build_files\windows\reset_variables.cmd"
9
10 call "%BLENDER_DIR%\build_files\windows\check_spaces_in_path.cmd"
11 if errorlevel 1 goto EOF
12
13 call "%BLENDER_DIR%\build_files\windows\parse_arguments.cmd" %*
14 if errorlevel 1 goto EOF
15
16 call "%BLENDER_DIR%\build_files\windows\find_dependencies.cmd"
17 if errorlevel 1 goto EOF
18
19 if "%BUILD_SHOW_HASHES%" == "1" (
20         call "%BLENDER_DIR%\build_files\windows\show_hashes.cmd"
21         goto EOF
22 )
23
24 if "%SHOW_HELP%" == "1" (
25         call "%BLENDER_DIR%\build_files\windows\show_help.cmd"
26         goto EOF
27 )
28
29 if "%BUILD_UPDATE%" == "1" (
30         call "%BLENDER_DIR%\build_files\windows\update_sources.cmd"
31         goto EOF
32 )
33
34
35 if "%FORMAT%" == "1" (
36         call "%BLENDER_DIR%\build_files\windows\format.cmd"
37         goto EOF
38 )
39
40 call "%BLENDER_DIR%\build_files\windows\detect_architecture.cmd"
41
42 if "%BUILD_VS_YEAR%" == "" (
43         call "%BLENDER_DIR%\build_files\windows\autodetect_msvc.cmd"
44         if errorlevel 1 (
45                 echo Visual Studio not found ^(try with the 'verbose' switch for more information^)
46                 goto EOF
47         )
48 ) else (
49         call "%BLENDER_DIR%\build_files\windows\detect_msvc%BUILD_VS_YEAR%.cmd"
50         if errorlevel 1 (
51                 echo Visual Studio %BUILD_VS_YEAR% not found ^(try with the 'verbose' switch for more information^)
52                 goto EOF
53         )
54 )
55
56 call "%BLENDER_DIR%\build_files\windows\set_build_dir.cmd"
57
58 echo Building blender with VS%BUILD_VS_YEAR% for %BUILD_ARCH% in %BUILD_DIR%
59
60 call "%BLENDER_DIR%\build_files\windows\check_libraries.cmd"
61 if errorlevel 1 goto EOF
62
63 call "%BLENDER_DIR%\build_files\windows\check_submodules.cmd"
64 if errorlevel 1 goto EOF
65
66 if "%BUILD_WITH_NINJA%" == "" (
67         call "%BLENDER_DIR%\build_files\windows\configure_msbuild.cmd"
68         if errorlevel 1 goto EOF
69
70         call "%BLENDER_DIR%\build_files\windows\build_msbuild.cmd"
71         if errorlevel 1 goto EOF
72 ) else (
73         call "%BLENDER_DIR%\build_files\windows\configure_ninja.cmd"
74         if errorlevel 1 goto EOF
75
76         call "%BLENDER_DIR%\build_files\windows\build_ninja.cmd"
77         if errorlevel 1 goto EOF
78 )
79
80 :EOF