ClangFormat: apply to source, most of intern
[blender.git] / intern / cycles / kernel / shaders / node_bump.osl
1 /*
2  * Copyright 2011-2013 Blender Foundation
3  *
4  * Licensed under the Apache License, Version 2.0 (the "License");
5  * you may not use this file except in compliance with the License.
6  * You may obtain a copy of the License at
7  *
8  * http://www.apache.org/licenses/LICENSE-2.0
9  *
10  * Unless required by applicable law or agreed to in writing, software
11  * distributed under the License is distributed on an "AS IS" BASIS,
12  * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
13  * See the License for the specific language governing permissions and
14  * limitations under the License.
15  */
16
17 #include "stdosl.h"
18
19 /* "Bump Mapping Unparameterized Surfaces on the GPU"
20  * Morten S. Mikkelsen, 2010 */
21
22 surface node_bump(int invert = 0,
23                   int use_object_space = 0,
24                   normal NormalIn = N,
25                   float Strength = 0.1,
26                   float Distance = 1.0,
27                   float SampleCenter = 0.0,
28                   float SampleX = 0.0,
29                   float SampleY = 0.0,
30                   output normal NormalOut = N)
31 {
32   point Ptmp = P;
33   normal Normal = NormalIn;
34
35   if (use_object_space) {
36     Ptmp = transform("object", Ptmp);
37     Normal = normalize(transform("object", Normal));
38   }
39
40   /* get surface tangents from normal */
41   vector dPdx = Dx(Ptmp);
42   vector dPdy = Dy(Ptmp);
43
44   vector Rx = cross(dPdy, Normal);
45   vector Ry = cross(Normal, dPdx);
46
47   /* compute surface gradient and determinant */
48   float det = dot(dPdx, Rx);
49   vector surfgrad = (SampleX - SampleCenter) * Rx + (SampleY - SampleCenter) * Ry;
50
51   float absdet = fabs(det);
52
53   float strength = max(Strength, 0.0);
54   float dist = Distance;
55
56   if (invert)
57     dist *= -1.0;
58
59   /* compute and output perturbed normal */
60   NormalOut = normalize(absdet * Normal - dist * sign(det) * surfgrad);
61   NormalOut = normalize(strength * NormalOut + (1.0 - strength) * Normal);
62
63   if (use_object_space) {
64     NormalOut = normalize(transform("object", "world", NormalOut));
65   }
66
67   NormalOut = ensure_valid_reflection(Ng, I, NormalOut);
68 }