Cycles: constant folding for RGB/Vector Curves and Color Ramp.
[blender.git] / intern / cycles / kernel / shaders / node_normal_map.osl
1 /*
2  * Copyright 2011-2013 Blender Foundation
3  *
4  * Licensed under the Apache License, Version 2.0 (the "License");
5  * you may not use this file except in compliance with the License.
6  * You may obtain a copy of the License at
7  *
8  * http://www.apache.org/licenses/LICENSE-2.0
9  *
10  * Unless required by applicable law or agreed to in writing, software
11  * distributed under the License is distributed on an "AS IS" BASIS,
12  * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
13  * See the License for the specific language governing permissions and
14  * limitations under the License.
15  */
16
17 #include "stdosl.h"
18
19 shader node_normal_map(
20         normal NormalIn = N,
21         float Strength = 1.0,
22         color Color = color(0.5, 0.5, 1.0),
23         string space = "tangent",
24         string attr_name = "geom:tangent",
25         string attr_sign_name = "geom:tangent_sign",
26         output normal Normal = NormalIn)
27 {
28         color mcolor = 2.0 * color(Color[0] - 0.5, Color[1] - 0.5, Color[2] - 0.5);
29
30         if (space == "tangent") {
31                 vector tangent;
32                 vector ninterp;
33                 float tangent_sign;
34                 float is_smooth;
35
36                 getattribute("geom:is_smooth", is_smooth);
37                 if (!is_smooth)
38                         ninterp = normalize(transform("world", "object", Ng));
39
40                 // get _unnormalized_ interpolated normal and tangent
41                 if (getattribute(attr_name, tangent) &&
42                     getattribute(attr_sign_name, tangent_sign) &&
43                     (!is_smooth || getattribute("geom:N", ninterp)))
44                 {
45                         // apply normal map
46                         vector B = tangent_sign * cross(ninterp, tangent);
47                         Normal = normalize(mcolor[0] * tangent + mcolor[1] * B + mcolor[2] * ninterp);
48
49                         // transform to world space
50                         Normal = normalize(transform("object", "world", Normal));
51                 }
52                 else {
53                         Normal = normal(0, 0, 0);
54                 }
55         }
56         else if (space == "object") {
57                 Normal = normalize(transform("object", "world", vector(mcolor)));
58         }
59         else if (space == "world") {
60                 Normal = normalize(vector(mcolor));
61         }
62         else if (space == "blender_object") {
63                 /* strange blender convention */
64                 mcolor[1] = -mcolor[1];
65                 mcolor[2] = -mcolor[2];
66         
67                 Normal = normalize(transform("object", "world", vector(mcolor)));
68         }
69         else if (space == "blender_world") {
70                 /* strange blender convention */
71                 mcolor[1] = -mcolor[1];
72                 mcolor[2] = -mcolor[2];
73         
74                 Normal = normalize(vector(mcolor));
75         }
76         
77         if (Strength != 1.0)
78                 Normal = normalize(NormalIn + (Normal - NormalIn) * max(Strength, 0.0));
79 }
80